Creating a nicely structured FP

The more complex a fight plan becomes, the higher the risk of getting completely lost with it. Having a nice structure to the plan helps, and also makes it easier to change the plan later to suit a different opponent.

With most of my plans, I'm following this "recipe":

#cheating notice

1) #universal lines

So, let's look at each one of these lines in turn, and fill up the commented parts to form an actual FP (where we assume to have an AGL advantage against a non-KP opponent).

Cheating notice

Remember what I said in my last entry? It's not always fun to lose to someone who's managed by Dr. Voodoo, or who's fighting 7 APs down, or without a FP. Make a note at the beginning whether you have a cheat line in there or not, it's going to save you a few embarrassing moments.

#UNIVERSAL CHEATING = ON

Opening line, endurance check and cut check

These are the lines at the very start of the FP - often the most important ones, too! We start out efficiently, upping the POW if not taking much damage, and targeting cuts should our opponent be unfortunate enough to suffer those early on.

#opening line
5B/7/8 (ring);

#cut check
if hiscuts > 2 then 5C/8/7 (ring);

Score blocks

These consist of score, endurance, stun and cut conditionals and form the backbone of the plan. The number of blocks varies in my fight plans, but for this example, I'll write just three.

#score block 1

if score < round - 7 then 7/5/8 (ring);
if score < round - 7 and endurance_percent > 100 - (round - 1)*4 then 7/6/7 (ring);
if score < round - 7 and endurance_percent > 100 - (round - 1)*3 then 7/6/7 (ropes);
if hiscuts > 4 and score > round - 9 then 5C/8/7 (ring);

Decision locked early

Sometimes your opponent either doesn't care about the score because he is going to knock you out late in the fight, or because he's just getting owned. So we have the decision locked up early - what now?

The most common method is to either just run away with 1/1/18 (ring) or go headhunting in the assumption that our opponent will likely now try to knock us out. This isn't always the optimal idea, as a Clincher manager may plan to start pounding you heavily to the body once the decision's lost, putting you in a nasty spot if you're going 4H/8/8 (ring). And in case your opponent is just getting owned, it's only fair to add some injuries to the insult. A nice defensive body line takes care of both!

#decision locked early

if score > 14 - round then 4B/5/11 (ring);

Endgame

The endgame starts at round 11 in our plan. For some plans I only write round 12 separately, and for others it may be from round 9 on (although that's rare, because I'm usually too lazy for that). Notice the allout line - we're desperate and our opponent seems to be slapping, so let fly.

11) #endgame, round 11

if score < 2 then 9/1/10 (ring);
if score < 2 and endurance_percent > 100 - (round - 1)*3 then 10/1/9 (ring);
if score < 2 and mystuns > hisstuns and endurance_percent < 72 and opp = 2 then 8/1/11 (ring);
if score < 1 then 10/1/9 (ring);
if score < 1 and endurance_percent > 100 - (round - 1)*3 then 11/1/8 (ring);
if score < 0 then 11/1/8 (ring);
if score < 0 and endurance_percent > 100 - (round - 1)*3 then 12/1/7 (ring);
if score < -1 and endurance_percent > 100 - (round - 1)*2 then 5H/10/5 (allout);

Cut explosion check

With this, I just want to make sure I pound my opponent should he suffer heavily from cuts.

1) #cut explosion check

if (score > round - 9 or score < round - 13) and hiscuts > 5 then 5C/9/6 (ropes);

Notice how the conditional works: the cut line kicks in only if we can still afford to lose rounds, or if we have practically already lost the fight and are desperate. In any case, it shouldn't kick in past round 11 (which would be pointless) so we make sure that it doesn't, by planning for the last round after this line.

if score < 3 then 10/1/9 (ring);
if score < 3 and endurance_percent > 100 - (round - 1)*3 then 11/1/8 (ring);
if score < 2 and mystuns > hisstuns and endurance_percent < 72 and opp = 2 then 8/1/11 (ring);
if score < 2 then 11/1/8 (ring);
if score < 2 and endurance_percent > 100 - (round - 1)*3 then 12/1/7 (ring);
if score < 1 and endurance_percent > 100 - (round - 1)*3 then 13/1/6 (ring);
if score < 0 and endurance_percent > 100 - (round - 1)*3 then 5H/10!/5 (allout);

Universal lines

Last but not least, we will add the universal lines to our plan. These include cheating, resting, opp=weak and toweling, plus some decision locked lines where we're too tired to fight back with a body or head line. It's always good to be pretty specific with these.

1) #universal lines

if opp = 2 and hiscuts < 3 and score < 2 and warnings = 0 and round < 7 then cheat;
if round = 8 and endurance_percent < 75 and opp = 2 and score > -1 and score < 12 - round then 1/1/8 (outside);
if opp = 0 and endurance_percent > 60 then 5H/10/5 (ropes);
if score > 13 - round and endurance_percent < 60 and opp = 2 then 1/1/18 (ring);
if score > 14 - round and endurance_percent < 65 then 1/1/18 (ring);
if endurance_percent < 55 and opp > score + 1 then towel

And there we have it, a nicely laid out FP that works like a clock. Not to mention that we can now use this as a template for much longer and complex FPs, which will then also work equally well (assuming you don't mess up the order of things, of course. Never happens to me though. Honest.)

FBG